1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 *  linux/boot/head.S
4 *
5 *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
6 */
7
8/*
9 *  head.S contains the 32-bit startup code.
10 *
11 * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
12 * the page directory will exist. The startup code will be overwritten by
13 * the page directory. [According to comments etc elsewhere on a compressed
14 * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
15 *
16 * Page 0 is deliberately kept safe, since System Management Mode code in
17 * laptops may need to access the BIOS data stored there.  This is also
18 * useful for future device drivers that either access the BIOS via VM86
19 * mode.
20 */
21
22/*
23 * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
24 */
25	.text
26
27#include <linux/init.h>
28#include <linux/linkage.h>
29#include <asm/segment.h>
30#include <asm/page_types.h>
31#include <asm/boot.h>
32#include <asm/asm-offsets.h>
33#include <asm/bootparam.h>
34
35/*
36 * These symbols needed to be marked as .hidden to prevent the BFD linker from
37 * generating R_386_32 (rather than R_386_RELATIVE) relocations for them when
38 * the 32-bit compressed kernel is linked as PIE. This is no longer necessary,
39 * but it doesn't hurt to keep them .hidden.
40 */
41	.hidden _bss
42	.hidden _ebss
43	.hidden _end
44
45	__HEAD
46SYM_FUNC_START(startup_32)
47	cld
48	cli
49
50/*
51 * Calculate the delta between where we were compiled to run
52 * at and where we were actually loaded at.  This can only be done
53 * with a short local call on x86.  Nothing  else will tell us what
54 * address we are running at.  The reserved chunk of the real-mode
55 * data at 0x1e4 (defined as a scratch field) are used as the stack
56 * for this calculation. Only 4 bytes are needed.
57 */
58	leal	(BP_scratch+4)(%esi), %esp
59	call	1f
601:	popl	%edx
61	addl	$_GLOBAL_OFFSET_TABLE_+(.-1b), %edx
62
63	/* Load new GDT */
64	leal	gdt@GOTOFF(%edx), %eax
65	movl	%eax, 2(%eax)
66	lgdt	(%eax)
67
68	/* Load segment registers with our descriptors */
69	movl	$__BOOT_DS, %eax
70	movl	%eax, %ds
71	movl	%eax, %es
72	movl	%eax, %fs
73	movl	%eax, %gs
74	movl	%eax, %ss
75
76/*
77 * %edx contains the address we are loaded at by the boot loader (plus the
78 * offset to the GOT).  The below code calculates %ebx to be the address where
79 * we should move the kernel image temporarily for safe in-place decompression
80 * (again, plus the offset to the GOT).
81 *
82 * %ebp is calculated to be the address that the kernel will be decompressed to.
83 */
84
85#ifdef CONFIG_RELOCATABLE
86	leal	startup_32@GOTOFF(%edx), %ebx
87
88#ifdef CONFIG_EFI_STUB
89/*
90 * If we were loaded via the EFI LoadImage service, startup_32() will be at an
91 * offset to the start of the space allocated for the image. efi_pe_entry() will
92 * set up image_offset to tell us where the image actually starts, so that we
93 * can use the full available buffer.
94 *	image_offset = startup_32 - image_base
95 * Otherwise image_offset will be zero and has no effect on the calculations.
96 */
97	subl    image_offset@GOTOFF(%edx), %ebx
98#endif
99
100	movl	BP_kernel_alignment(%esi), %eax
101	decl	%eax
102	addl    %eax, %ebx
103	notl	%eax
104	andl    %eax, %ebx
105	cmpl	$LOAD_PHYSICAL_ADDR, %ebx
106	jae	1f
107#endif
108	movl	$LOAD_PHYSICAL_ADDR, %ebx
1091:
110
111	movl	%ebx, %ebp	// Save the output address for later
112	/* Target address to relocate to for decompression */
113	addl    BP_init_size(%esi), %ebx
114	subl    $_end@GOTOFF, %ebx
115
116	/* Set up the stack */
117	leal	boot_stack_end@GOTOFF(%ebx), %esp
118
119	/* Zero EFLAGS */
120	pushl	$0
121	popfl
122
123/*
124 * Copy the compressed kernel to the end of our buffer
125 * where decompression in place becomes safe.
126 */
127	pushl	%esi
128	leal	(_bss@GOTOFF-4)(%edx), %esi
129	leal	(_bss@GOTOFF-4)(%ebx), %edi
130	movl	$(_bss - startup_32), %ecx
131	shrl	$2, %ecx
132	std
133	rep	movsl
134	cld
135	popl	%esi
136
137	/*
138	 * The GDT may get overwritten either during the copy we just did or
139	 * during extract_kernel below. To avoid any issues, repoint the GDTR
140	 * to the new copy of the GDT.
141	 */
142	leal	gdt@GOTOFF(%ebx), %eax
143	movl	%eax, 2(%eax)
144	lgdt	(%eax)
145
146/*
147 * Jump to the relocated address.
148 */
149	leal	.Lrelocated@GOTOFF(%ebx), %eax
150	jmp	*%eax
151SYM_FUNC_END(startup_32)
152
153#ifdef CONFIG_EFI_STUB
154SYM_FUNC_START(efi32_stub_entry)
155	add	$0x4, %esp
156	movl	8(%esp), %esi	/* save boot_params pointer */
157	call	efi_main
158	/* efi_main returns the possibly relocated address of startup_32 */
159	jmp	*%eax
160SYM_FUNC_END(efi32_stub_entry)
161SYM_FUNC_ALIAS(efi_stub_entry, efi32_stub_entry)
162#endif
163
164	.text
165SYM_FUNC_START_LOCAL_NOALIGN(.Lrelocated)
166
167/*
168 * Clear BSS (stack is currently empty)
169 */
170	xorl	%eax, %eax
171	leal	_bss@GOTOFF(%ebx), %edi
172	leal	_ebss@GOTOFF(%ebx), %ecx
173	subl	%edi, %ecx
174	shrl	$2, %ecx
175	rep	stosl
176
177/*
178 * Do the extraction, and jump to the new kernel..
179 */
180	/* push arguments for extract_kernel: */
181
182	pushl	output_len@GOTOFF(%ebx)	/* decompressed length, end of relocs */
183	pushl	%ebp			/* output address */
184	pushl	input_len@GOTOFF(%ebx)	/* input_len */
185	leal	input_data@GOTOFF(%ebx), %eax
186	pushl	%eax			/* input_data */
187	leal	boot_heap@GOTOFF(%ebx), %eax
188	pushl	%eax			/* heap area */
189	pushl	%esi			/* real mode pointer */
190	call	extract_kernel		/* returns kernel location in %eax */
191	addl	$24, %esp
192
193/*
194 * Jump to the extracted kernel.
195 */
196	xorl	%ebx, %ebx
197	jmp	*%eax
198SYM_FUNC_END(.Lrelocated)
199
200	.data
201	.balign	8
202SYM_DATA_START_LOCAL(gdt)
203	.word	gdt_end - gdt - 1
204	.long	0
205	.word	0
206	.quad	0x0000000000000000	/* Reserved */
207	.quad	0x00cf9a000000ffff	/* __KERNEL_CS */
208	.quad	0x00cf92000000ffff	/* __KERNEL_DS */
209SYM_DATA_END_LABEL(gdt, SYM_L_LOCAL, gdt_end)
210
211#ifdef CONFIG_EFI_STUB
212SYM_DATA(image_offset, .long 0)
213#endif
214
215/*
216 * Stack and heap for uncompression
217 */
218	.bss
219	.balign 4
220boot_heap:
221	.fill BOOT_HEAP_SIZE, 1, 0
222boot_stack:
223	.fill BOOT_STACK_SIZE, 1, 0
224boot_stack_end:
225