1.file "rint.s"
2
3
4// Copyright (c) 2000 - 2003, Intel Corporation
5// All rights reserved.
6//
7//
8// Redistribution and use in source and binary forms, with or without
9// modification, are permitted provided that the following conditions are
10// met:
11//
12// * Redistributions of source code must retain the above copyright
13// notice, this list of conditions and the following disclaimer.
14//
15// * Redistributions in binary form must reproduce the above copyright
16// notice, this list of conditions and the following disclaimer in the
17// documentation and/or other materials provided with the distribution.
18//
19// * The name of Intel Corporation may not be used to endorse or promote
20// products derived from this software without specific prior written
21// permission.
22
23// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
24// "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
25// LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
26// A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
27// CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
28// EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
29// PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
30// PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
31// OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
32// NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
33// SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
34//
35// Intel Corporation is the author of this code, and requests that all
36// problem reports or change requests be submitted to it directly at
37// http://www.intel.com/software/products/opensource/libraries/num.htm.
38//
39// History
40//==============================================================
41// 02/02/00 Initial version
42// 02/08/01 Corrected behavior for all rounding modes.
43// 05/20/02 Cleaned up namespace and sf0 syntax
44// 01/20/03 Improved performance
45//==============================================================
46
47// API
48//==============================================================
49// double rint(double x)
50//==============================================================
51
52// general input registers:
53// r14 - r21
54
55rSignexp   = r14
56rExp       = r15
57rExpMask   = r16
58rBigexp    = r17
59rM1        = r18
60rFpsr      = r19
61rRcs0      = r20
62rRcs0Mask  = r21
63
64// floating-point registers:
65// f8 - f11
66
67fXInt      = f9
68fNormX     = f10
69fTmp       = f11
70
71// predicate registers used:
72// p6 - p10
73
74// Overview of operation
75//==============================================================
76// double rint(double x)
77// Return an integer value (represented as a double) that is x
78// rounded to integer in current rounding mode
79// Inexact is set if x != rint(x)
80//==============================================================
81
82// double_extended
83// if the exponent is > 1003e => 3F(true) = 63(decimal)
84// we have a significand of 64 bits 1.63-bits.
85// If we multiply by 2^63, we no longer have a fractional part
86// So input is an integer value already.
87
88// double
89// if the exponent is >= 10033 => 34(true) = 52(decimal)
90// 34 + 3ff = 433
91// we have a significand of 53 bits 1.52-bits. (implicit 1)
92// If we multiply by 2^52, we no longer have a fractional part
93// So input is an integer value already.
94
95// single
96// if the exponent is > 10016 => 17(true) = 23(decimal)
97// we have a significand of 24 bits 1.23-bits. (implicit 1)
98// If we multiply by 2^23, we no longer have a fractional part
99// So input is an integer value already.
100
101.section .text
102GLOBAL_IEEE754_ENTRY(rint)
103
104{ .mfi
105      getf.exp         rSignexp  = f8        // Get signexp, recompute if unorm
106      fclass.m         p7,p0 = f8, 0x0b      // Test x unorm
107      addl             rBigexp = 0x10033, r0 // Set exponent at which is integer
108}
109{ .mfi
110      mov              rM1 = -1              // Set all ones
111      fcvt.fx.s1       fXInt  = f8           // Convert to int in significand
112      mov              rExpMask    = 0x1FFFF // Form exponent mask
113}
114;;
115
116{ .mfi
117      mov              rFpsr = ar40          // Read fpsr -- check rc.s0
118      fclass.m         p6,p0 = f8, 0x1e3     // Test x natval, nan, inf
119      nop.i            0
120}
121{ .mfb
122      setf.sig         fTmp = rM1            // Make const for setting inexact
123      fnorm.s1         fNormX  = f8          // Normalize input
124(p7)  br.cond.spnt     RINT_UNORM            // Branch if x unorm
125}
126;;
127
128
129RINT_COMMON:
130// Return here from RINT_UNORM
131{ .mfb
132      and              rExp = rSignexp, rExpMask // Get biased exponent
133(p6)  fma.d.s0         f8 = f8, f1, f0       // Result if x natval, nan, inf
134(p6)  br.ret.spnt      b0                    // Exit if x natval, nan, inf
135}
136;;
137
138{ .mfi
139      mov              rRcs0Mask = 0x0c00     // Mask for rc.s0
140      fcvt.xf          f8 = fXInt             // Result assume |x| < 2^52
141      cmp.ge           p7,p8 = rExp, rBigexp  // Is |x| >= 2^52?
142}
143;;
144
145// We must correct result if |x| >= 2^52
146{ .mfi
147      nop.m            0
148(p7)  fma.d.s0         f8 = fNormX, f1, f0    // If |x| >= 2^52, result x
149      nop.i            0
150}
151;;
152
153{ .mfi
154      nop.m            0
155      fcmp.eq.unc.s1   p0, p9 = f8, fNormX    // Is result = x ?
156      nop.i            0
157}
158{ .mfi
159      nop.m            0
160(p8)  fmerge.s         f8 = fNormX, f8        // Make sure sign rint(x) = sign x
161      nop.i            0
162}
163;;
164
165{ .mfi
166(p8)  and              rRcs0 = rFpsr, rRcs0Mask // Get rounding mode for sf0
167      nop.f            0
168      nop.i            0
169}
170;;
171
172// If |x| < 2^52 we must test for other rounding modes
173{ .mfi
174(p8)  cmp.ne.unc       p10,p0 = rRcs0, r0     // Test for other rounding modes
175(p9)  fmpy.s0          fTmp = fTmp, fTmp      // Dummy to set inexact
176      nop.i            0
177}
178{ .mbb
179      nop.m            0
180(p10) br.cond.spnt     RINT_NOT_ROUND_NEAREST // Branch if not round nearest
181      br.ret.sptk      b0                     // Exit main path if round nearest
182}
183;;
184
185
186
187RINT_UNORM:
188// Here if x unorm
189{ .mfb
190      getf.exp         rSignexp  = fNormX     // Get signexp, recompute if unorm
191      fcmp.eq.s0       p7,p0 = f8, f0         // Dummy op to set denormal flag
192      br.cond.sptk     RINT_COMMON            // Return to main path
193}
194;;
195
196RINT_NOT_ROUND_NEAREST:
197// Here if not round to nearest, and |x| < 2^52
198// Set rounding mode of s2 to that of s0, and repeat the conversion using s2
199{ .mfi
200      nop.m            0
201      fsetc.s2         0x7f, 0x40
202      nop.i            0
203}
204;;
205
206{ .mfi
207      nop.m            0
208      fcvt.fx.s2       fXInt  = fNormX        // Convert to int in significand
209      nop.i            0
210}
211;;
212
213{ .mfi
214      nop.m            0
215      fcvt.xf          f8 = fXInt             // Expected result
216      nop.i            0
217}
218;;
219
220// Be sure sign of result = sign of input.  Fixes cases where result is 0.
221{ .mfb
222      nop.m            0
223      fmerge.s         f8 = fNormX, f8
224      br.ret.sptk      b0                     // Exit main path
225}
226;;
227
228GLOBAL_IEEE754_END(rint)
229libm_alias_double_other (__rint, rint)
230