xref: /DragonStub/gnuefi/elf_mips64el_efi.lds (revision 9c5403e1e6269bd47a4c383cfeaf1a4f29db121f) 
1OUTPUT_FORMAT("elf64-tradlittlemips", "elf64-tradbigmips", "elf64-tradlittlemips")
2OUTPUT_ARCH(mips)
3ENTRY(_start)
4SECTIONS
5{
6  .text 0x0 : {
7    _text = .;
8    *(.text.head)
9    *(.text)
10    *(.text.*)
11    *(.gnu.linkonce.t.*)
12    *(.srodata)
13    *(.rodata*)
14    . = ALIGN(16);
15  }
16  _etext = .;
17  _text_size = . - _text;
18  . = DATA_SEGMENT_ALIGN (CONSTANT (MAXPAGESIZE), CONSTANT (COMMONPAGESIZE));
19  .dynamic  : { *(.dynamic) }
20  . = ALIGN(4096);
21  .data :
22  {
23   _data = .;
24   *(.sdata)
25   *(.data)
26   *(.data1)
27   *(.data.*)
28   *(.got.plt)
29   HIDDEN (_gp = ALIGN (16) + 0x7ff0);
30   *(.got)
31
32   /*
33    * Note that these aren't the using the GNU "CONSTRUCTOR" output section
34    * command, so they don't start with a size.  Because of p2align and the
35    * end/END definitions, and the fact that they're mergeable, they can also
36    * have NULLs which aren't guaranteed to be at the end.
37    */
38   . = ALIGN(16);
39   __init_array_start = .;
40   *(SORT(.init_array.*))
41   *(.init_array)
42   __init_array_end = .;
43   __CTOR_LIST__ = .;
44   *(SORT(.ctors.*))
45   *(.ctors)
46   __CTOR_END__ = .;
47   __DTOR_LIST__ = .;
48   *(SORT(.dtors.*))
49   *(.dtors)
50   __DTOR_END__ = .;
51   __fini_array_start = .;
52   *(SORT(.fini_array.*))
53   *(.fini_array)
54   __fini_array_end = .;
55
56   /* the EFI loader doesn't seem to like a .bss section, so we stick
57      it all into .data: */
58   . = ALIGN(16);
59   _bss = .;
60   *(.sbss)
61   *(.scommon)
62   *(.dynbss)
63   *(.bss*)
64   *(COMMON)
65   . = ALIGN(16);
66   _bss_end = .;
67  }
68
69  . = ALIGN(4096);
70  .rel :
71  {
72    *(.rel.text*)
73    *(.rel.data*)
74    *(.rel.got)
75    *(.rel.dyn)
76    *(.rel.stab)
77    *(.rel.init_array*)
78    *(.rel.fini_array*)
79    *(.rel.ctors*)
80    *(.rel.dtors*)
81  }
82  . = ALIGN(4096);
83  .rel.plt : { *(.rel.plt) }
84  _edata = .;
85  _data_size = . - _etext;
86
87  . = ALIGN(4096);
88  .dynsym   : { *(.dynsym) }
89  . = ALIGN(4096);
90  .dynstr   : { *(.dynstr) }
91  . = ALIGN(4096);
92  .note.gnu.build-id : { *(.note.gnu.build-id) }
93  . = DATA_SEGMENT_END (.);
94  /DISCARD/ :
95  {
96    *(.rel.reloc)
97    *(.eh_frame)
98    *(.MIPS.abiflags)
99    *(.note.GNU-stack)
100  }
101  .comment 0 : { *(.comment) }
102}
103