xref: /DragonStub/gnuefi/elf_mips64el_efi.lds (revision 574b48d8e4008748975e847dc8c996cd4681789f) 
1OUTPUT_FORMAT("elf64-tradlittlemips", "elf64-tradbigmips", "elf64-tradlittlemips")
2OUTPUT_ARCH(mips)
3ENTRY(_start)
4SECTIONS
5{
6  .text 0x0 : {
7    _text = .;
8    *(.text.head)
9    *(.text)
10    *(.text.*)
11    *(.gnu.linkonce.t.*)
12    *(.srodata)
13    *(.rodata*)
14    . = ALIGN(16);
15  }
16  _etext = .;
17  _text_size = . - _text;
18  .dynamic  : { *(.dynamic) }
19  .data :
20  {
21   _data = .;
22   *(.sdata)
23   *(.data)
24   *(.data1)
25   *(.data.*)
26   *(.got.plt)
27   HIDDEN (_gp = ALIGN (16) + 0x7ff0);
28   *(.got)
29
30   /* the EFI loader doesn't seem to like a .bss section, so we stick
31      it all into .data: */
32   . = ALIGN(16);
33   _bss = .;
34   *(.sbss)
35   *(.scommon)
36   *(.dynbss)
37   *(.bss)
38   *(COMMON)
39   . = ALIGN(16);
40   _bss_end = .;
41  }
42
43  .rel.dyn : { *(.rel.dyn) }
44  .rel.plt : { *(.rel.plt) }
45  .rel.got : { *(.rel.got) }
46  .rel.data : { *(.rel.data) *(.rel.data*) }
47  _edata = .;
48  _data_size = . - _etext;
49
50  . = ALIGN(4096);
51  .dynsym   : { *(.dynsym) }
52  . = ALIGN(4096);
53  .dynstr   : { *(.dynstr) }
54  . = ALIGN(4096);
55  .note.gnu.build-id : { *(.note.gnu.build-id) }
56  /DISCARD/ :
57  {
58    *(.rel.reloc)
59    *(.eh_frame)
60    *(.MIPS.abiflags)
61    *(.note.GNU-stack)
62  }
63  .comment 0 : { *(.comment) }
64}
65