xref: /DragonStub/gnuefi/elf_loongarch64_efi.lds (revision 20110935449a7b378c48ee924b0c8ed049bfae80) 
1OUTPUT_FORMAT("elf64-loongarch", "elf64-loongarch", "elf64-loongarch")
2OUTPUT_ARCH(loongarch)
3ENTRY(_start)
4SECTIONS
5{
6  .text 0x0 : {
7    _text = .;
8    *(.text.head)
9    *(.text)
10    *(.text.*)
11    *(.gnu.linkonce.t.*)
12    *(.srodata)
13    *(.rodata*)
14    . = ALIGN(16);
15  }
16  _etext = .;
17  _text_size = _etext - _text;
18  .dynamic  : { *(.dynamic) }
19  .data : ALIGN(4096)
20  {
21   _data = .;
22   *(.sdata)
23   *(.data)
24   *(.data1)
25   *(.data.*)
26   *(.got.plt)
27   *(.got)
28
29   /* the EFI loader doesn't seem to like a .bss section, so we stick
30      it all into .data: */
31   . = ALIGN(16);
32   _bss = .;
33   *(.sbss)
34   *(.scommon)
35   *(.dynbss)
36   *(.bss)
37   *(COMMON)
38   . = ALIGN(16);
39   _bss_end = .;
40  }
41
42  .rela.dyn : { *(.rela.dyn) }
43  .rela.plt : { *(.rela.plt) }
44  .rela.got : { *(.rela.got) }
45  .rela.data : { *(.rela.data) *(.rela.data*) }
46  . = ALIGN(512);
47  _edata = .;
48  _data_size = _edata - _data;
49
50  . = ALIGN(4096);
51  .dynsym   : { *(.dynsym) }
52  . = ALIGN(4096);
53  .dynstr   : { *(.dynstr) }
54  . = ALIGN(4096);
55  .note.gnu.build-id : { *(.note.gnu.build-id) }
56  /DISCARD/ :
57  {
58    *(.rel.reloc)
59    *(.eh_frame)
60    *(.note.GNU-stack)
61  }
62  .comment 0 : { *(.comment) }
63}
64