xref: /DragonStub/gnuefi/elf_ia64_efi.lds (revision cc4ef911ee2ccd47411df410dc161a35b8b35d01) 
1OUTPUT_FORMAT("elf64-ia64-little")
2OUTPUT_ARCH(ia64)
3ENTRY(_start_plabel)
4SECTIONS
5{
6  . = 0;
7  ImageBase = .;
8  /* .hash and/or .gnu.hash MUST come first! */
9  .hash : { *(.hash) }
10  .gnu.hash : { *(.gnu.hash) }
11  .eh_frame : { *(.eh_frame) }
12  .gcc_except_table : { *(.gcc_except_table*) }
13  . = ALIGN(4096);
14  .text :
15  {
16   _text = .;
17   *(.text)
18   *(.text.*)
19   *(.gnu.linkonce.t.*)
20   . = ALIGN(16);
21  }
22  _etext = .;
23  _text_size = . - _text;
24  . = DATA_SEGMENT_ALIGN (CONSTANT (MAXPAGESIZE), CONSTANT (COMMONPAGESIZE));
25  __gp = ALIGN (8) + 0x200000;
26  .sdata :
27  {
28   _data = .;
29   *(.got.plt)
30   *(.got)
31   *(.srodata)
32   *(.sdata)
33   *(.sbss)
34   *(.scommon)
35  }
36  . = ALIGN(4096);
37  .data :
38  {
39   *(.rodata*)
40   *(.ctors)
41   *(.data*)
42   *(.gnu.linkonce.d*)
43   *(.plabel)	/* data whose relocs we want to ignore */
44   /* the EFI loader doesn't seem to like a .bss section, so we stick
45      it all into .data: */
46   *(.dynbss)
47   *(.bss*)
48   *(COMMON)
49  }
50  .note.gnu.build-id : { *(.note.gnu.build-id) }
51
52  . = ALIGN(4096);
53  .dynamic  : { *(.dynamic) }
54  . = ALIGN(4096);
55  .rela :
56  {
57    *(.rela.text*)
58    *(.rela.sdata*)
59    *(.rela.data*)
60    *(.rela.got)
61    *(.rela.dyn)
62    *(.rela.gnu.linkonce.d*)
63    *(.rela.stab)
64    *(.rela.ctors)
65  }
66  . = ALIGN(4096);
67  .rela.plt : { *(.rela.plt) }
68  _edata = .;
69  _data_size = . - _etext;
70  . = ALIGN(4096);
71  .reloc :		/* This is the PECOFF .reloc section! */
72  {
73    KEEP (*(.reloc))
74  }
75  . = ALIGN(4096);
76  .dynsym   : { *(.dynsym) }
77  . = ALIGN(4096);
78  .dynstr   : { *(.dynstr) }
79  . = DATA_SEGMENT_END (.);
80  /DISCARD/ :
81  {
82    *(.rela.plabel)
83    *(.rela.reloc)
84    *(.IA_64.unwind*)
85    *(.IA64.unwind*)
86  }
87}
88