xref: /DragonStub/gnuefi/elf_ia64_efi.lds (revision 4f8b339facb471192e021fffd5db545a0fbddbc3) 
1OUTPUT_FORMAT("elf64-ia64-little")
2OUTPUT_ARCH(ia64)
3ENTRY(_start_plabel)
4SECTIONS
5{
6  . = 0;
7  ImageBase = .;
8  /* .hash and/or .gnu.hash MUST come first! */
9  .hash : { *(.hash) }
10  .gnu.hash : { *(.gnu.hash) }
11  .eh_frame : { *(.eh_frame) }
12  .gcc_except_table : { *(.gcc_except_table*) }
13  . = ALIGN(4096);
14  .text :
15  {
16   _text = .;
17   *(.text)
18   *(.text.*)
19   *(.gnu.linkonce.t.*)
20   . = ALIGN(16);
21  }
22  _etext = .;
23  _text_size = . - _text;
24  . = DATA_SEGMENT_ALIGN (CONSTANT (MAXPAGESIZE), CONSTANT (COMMONPAGESIZE));
25  __gp = ALIGN (8) + 0x200000;
26  .sdata :
27  {
28   _data = .;
29   *(.got.plt)
30   *(.got)
31   *(.srodata)
32   *(.sdata)
33   *(.sbss)
34   *(.scommon)
35  }
36  . = ALIGN(4096);
37  .data :
38  {
39   *(.rodata*)
40   *(.ctors)
41   *(.data*)
42   *(.gnu.linkonce.d*)
43   *(.plabel)	/* data whose relocs we want to ignore */
44
45   /*
46    * Note that these aren't the using the GNU "CONSTRUCTOR" output section
47    * command, so they don't start with a size.  Because of p2align and the
48    * end/END definitions, and the fact that they're mergeable, they can also
49    * have NULLs which aren't guaranteed to be at the end.
50    */
51   . = ALIGN(16);
52   _init_array = .;
53   *(SORT_BY_NAME(.init_array))
54   _init_array_end = .;
55   __CTOR_LIST__ = .;
56   *(SORT_BY_NAME(.ctors))
57   __CTOR_END__ = .;
58   __DTOR_LIST__ = .;
59   *(SORT_BY_NAME(.dtors))
60   __DTOR_END__ = .;
61   _fini_array = .;
62   *(SORT_BY_NAME(.fini_array))
63   _fini_array_end = .;
64
65   /* the EFI loader doesn't seem to like a .bss section, so we stick
66      it all into .data: */
67   *(.dynbss)
68   *(.bss*)
69   *(COMMON)
70  }
71  .note.gnu.build-id : { *(.note.gnu.build-id) }
72
73  . = ALIGN(4096);
74  .dynamic  : { *(.dynamic) }
75  . = ALIGN(4096);
76  .rela :
77  {
78    *(.rela.text*)
79    *(.rela.sdata*)
80    *(.rela.data*)
81    *(.rela.got)
82    *(.rela.dyn)
83    *(.rela.gnu.linkonce.d*)
84    *(.rela.stab)
85    *(.rela.ctors)
86  }
87  . = ALIGN(4096);
88  .rela.plt : { *(.rela.plt) }
89  _edata = .;
90  _data_size = . - _etext;
91  . = ALIGN(4096);
92  .reloc :		/* This is the PECOFF .reloc section! */
93  {
94    KEEP (*(.reloc))
95  }
96  . = ALIGN(4096);
97  .dynsym   : { *(.dynsym) }
98  . = ALIGN(4096);
99  .dynstr   : { *(.dynstr) }
100  . = DATA_SEGMENT_END (.);
101  /DISCARD/ :
102  {
103    *(.rela.plabel)
104    *(.rela.reloc)
105    *(.IA_64.unwind*)
106    *(.IA64.unwind*)
107  }
108}
109