xref: /DragonStub/gnuefi/elf_arm_efi.lds (revision 88e3cf95351175bed27a6e714b83b6f2390348f1) 
1OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
2OUTPUT_ARCH(arm)
3ENTRY(_start)
4SECTIONS
5{
6  .text 0x0 : {
7    _text = .;
8    *(.text.head)
9    *(.text)
10    *(.text.*)
11    *(.gnu.linkonce.t.*)
12    *(.srodata)
13    *(.rodata*)
14    . = ALIGN(16);
15  }
16  _etext = .;
17  _text_size = . - _text;
18  .dynamic  : { *(.dynamic) }
19  .data :
20  {
21   _data = .;
22   *(.sdata)
23   *(.data)
24   *(.data1)
25   *(.data)
26   *(.got.plt)
27   *(.got)
28
29   /* the EFI loader doesn't seem to like a .bss section, so we stick
30      it all into .data: */
31   . = ALIGN(16);
32   _bss = .;
33   *(.sbss)
34   *(.scommon)
35   *(.dynbss)
36   *(.bss)
37   *(COMMON)
38   . = ALIGN(16);
39   _bss_end = .;
40  }
41  .rel.dyn : { *(.rel.dyn) }
42  .rel.plt : { *(.rel.plt) }
43  .rel.got : { *(.rel.got) }
44  .rel.data : { *(.rel.data) *(.rel.data*) }
45  _edata = .;
46  _data_size = . - _etext;
47
48  . = ALIGN(4096);
49  .dynsym   : { *(.dynsym) }
50  . = ALIGN(4096);
51  .dynstr   : { *(.dynstr) }
52  . = ALIGN(4096);
53  /DISCARD/ :
54  {
55    *(.rel.reloc)
56    *(.eh_frame)
57    *(.note.GNU-stack)
58  }
59  .comment 0 : { *(.comment) }
60}
61