xref: /DragonStub/gnuefi/elf_aarch64_efi.lds (revision 3dd05c7b21921cae0002ab7964fa0e52dedd7c3f) 
1OUTPUT_FORMAT("elf64-littleaarch64", "elf64-littleaarch64", "elf64-littleaarch64")
2OUTPUT_ARCH(aarch64)
3ENTRY(_start)
4SECTIONS
5{
6  .text 0x0 : {
7    _text = .;
8    *(.text.head)
9    *(.text)
10    *(.text.*)
11    *(.gnu.linkonce.t.*)
12    *(.srodata)
13    *(.rodata*)
14    . = ALIGN(16);
15  }
16  _etext = .;
17  _text_size = . - _text;
18  .dynamic  : { *(.dynamic) }
19  .data :
20  {
21   _data = .;
22   *(.sdata)
23   *(.data)
24   *(.data1)
25   *(.data.*)
26   *(.got.plt)
27   *(.got)
28
29   /* the EFI loader doesn't seem to like a .bss section, so we stick
30      it all into .data: */
31   . = ALIGN(16);
32   _bss = .;
33   *(.sbss)
34   *(.scommon)
35   *(.dynbss)
36   *(.bss)
37   *(COMMON)
38   . = ALIGN(16);
39   _bss_end = .;
40  }
41
42  .rela.dyn : { *(.rela.dyn) }
43  .rela.plt : { *(.rela.plt) }
44  .rela.got : { *(.rela.got) }
45  .rela.data : { *(.rela.data) *(.rela.data*) }
46  _edata = .;
47  _data_size = . - _etext;
48
49  . = ALIGN(4096);
50  .dynsym   : { *(.dynsym) }
51  . = ALIGN(4096);
52  .dynstr   : { *(.dynstr) }
53  . = ALIGN(4096);
54  .note.gnu.build-id : { *(.note.gnu.build-id) }
55  /DISCARD/ :
56  {
57    *(.rel.reloc)
58    *(.eh_frame)
59    *(.note.GNU-stack)
60  }
61  .comment 0 : { *(.comment) }
62}
63